#NoTrayIcon
#SingleInstance off
windowTitle := "Wget GUI v1.3"

	Gui, Add, Text, x16 y14 w740 h20 , Choose URL and options, than press run. (Return = Run and Quit, Strg+Return = Run)

	Gui, Add, GroupBox, x16 y44 w740 h50 , URL
	Gui, Add, Edit, x26 y64 w720 h20 gURLchanged vURL,

	Gui, Add, GroupBox, x16 y104 w740 h80 , Output Folder and Filename
	Gui, Add, Edit, x26 y124 w670 h20 vFolder,%USERPROFILE%\Desktop
	Gui, Add, Button, x706 y124 w40 h20 -Wrap gChooseFolder, ...
	Gui, Add, Text, x26 y157 w120 h20 , Force different Filename: 
	Gui, Add, Edit, x166 y154 w580 h20 gOutputChanged vOutput, 

	Gui, Add, GroupBox, x16 y194 w740 h110 , Options
	Gui, Add, CheckBox, x26 y214 w130 h20 gContinueChanged vContinue, Continue Download
	Gui, Add, CheckBox, x166 y214 w320 h20 gRetriesChanged vRetries, Infinite Retries
	Gui, Add, Text, x26 y247 w120 h20 , Use different user agent:
	Gui, Add, DropDownList, x166 y244 w180 Choose1 gUserAgentChanged vUserAgent, Standard wGet|Firefox 2|IE 6|Flash
	Gui, Add, Text, x370 y247 w120 h20 , Limit Download Rate:
	Gui, Add, Edit, x490 y244 w40 h20 gRateChanged vRate,
	Gui, Add, Text, x535 y247 w120 h20 , K/s
	Gui, Add, Text, x26 y277 w120 h20 , Referer:
	Gui, Add, Edit, x166 y274 w580 h20 gRefererChanged vReferer,

	Gui, Add, Text, x26 y317 w90 h20 , Command line:
	Gui, Add, Edit, x116 y314 w630 h20 vCommandLine, wget.exe

	Gui, Add, Button, x426 y344 w100 h30 -Wrap, Run and Quit
	Gui, Add, Button, x536 y344 w100 h30 -Wrap, Run
	Gui, Add, Button, x646 y344 w100 h30 -Wrap, Quit
	;invisible Default Button
	Gui, Add, Button, x0 y0 w0 h0 -Wrap Default, Enter

	Gui, Show, x163 y113 h386 w778, %windowTitle%

	Gosub, CheckClipboardForURL
Return

GuiEscape:
GuiClose:
ButtonQuit:
	ExitApp
Return

ButtonRun:
	GuiControlGet, CommandLine
	GuiControlGet, Folder
	Run, %CommandLine% , %Folder%
Return

ButtonRunandQuit:
	Gosub, ButtonRun
	ExitApp
Return

ButtonEnter:
	If (GetKeyState("Control"))
		{
		Gosub, ButtonRun
		}
	Else
		{
		Gosub, ButtonRunandQuit
		}
Return

URLChanged:
	GuiControlGet, URL
	Gui, Show,, %URL% - %windowTitle%
	GoSub, ComposeCommandLine
Return

UserAgentChanged:
	GuiControlGet, UserAgent
	if (UserAgent = "Firefox 2")
        {
        cUserAgent := "--user-agent=""Mozilla/5.0 (Windows; U; Windows NT 5.1; de; rv:1.8.1.12) Gecko/20080201 Firefox/2.0.0.12"" "
        }
    else if (UserAgent = "IE 6")
        {
        cUserAgent := "--user-agent=""Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.1; SV1)"" "
        }
    else if (UserAgent = "Flash/Safari on Mac")
        {
        cUserAgent := "--user-agent=""Mozilla/5.0 (Macintosh; U; PPC Mac OS X; en) AppleWebKit/420+ (KHTML, like Gecko) Safari/419.3 Apollo/1.0"" "
        }
    else
        {
        cUserAgent := ""
        }
	GoSub, ComposeCommandLine
Return

OutputChanged:
	GuiControlGet, Output
	if (Output <> "")
        {
        cOutput := "-O """ . Output . """ "
        }
    else
        {
        cOutput := ""
        }
	GoSub, ComposeCommandLine
Return

RefererChanged:
	GuiControlGet, Referer
	if (Referer <> "")
        {
        cReferer := "--referer=""" . Referer . """ "
        }
    else
        {
        cReferer := ""
        }
	GoSub, ComposeCommandLine
Return

ContinueChanged:
	GuiControlGet, Continue
	if (Continue = 1)
        {
        cContinue := "-c "
        }
    else
        {
        cContinue := ""
        }
	GoSub, ComposeCommandLine
Return

RetriesChanged:
	GuiControlGet, Retries
	if (Retries = 1)
        {
        cRetries := "--tries=0 "
        }
    else
        {
        cRetries := ""
        }
	GoSub, ComposeCommandLine
Return

RateChanged:
	GuiControlGet, Rate
	if (Rate <> "")
        {
        cRate := "--limit-rate=""" . Rate * 1024 . """ "
        }
    else
        {
        cRate := ""
        }
	GoSub, ComposeCommandLine
Return

ChooseFolder:
	FileSelectFolder, Folder
	GuiControl, Text, Folder, %Folder%
Return

ComposeCommandLine:
	Gui, Submit, NoHide
	GuiControl, Text, CommandLine, wget.exe %cContinue%%cRetries%%cRate%%cUserAgent%%cReferer%%cOutput%"%URL%"
Return

CheckClipboardForURL:
	;%clipboard%
	if (InStr(clipboard, "http://") or InStr(clipboard, "https://") or InStr(clipboard, "ftp://") or InStr(clipboard, "www."))
        {
        GuiControl, Text, URL, %clipboard%
        }
Return